***********************************************************************
***********           PANJIT International Inc.             ***********
***********************************************************************
*May 20, 2024                                                         *
*                                                                     *
*This SPICE Model describes the characteristics of a typical device   *
*and does not respresent the specification. Designer should refer to  *
*the same type name data sheet for specification limits.              *
***********************************************************************
*$
.subckt PEC3815CS-AU 1 2
.param
+vc0 = 7.011e-10	 vc1 = 8.885e-11   	 vc2 = 6.8132e-1		 vc3 = 5.591e-12		 vc4 = 1.590e-1
+tc1 = 8.581e-3		 tc2 = 1.921e-2		 tc3 = 8.291e-2		 tc4 = 2.201e-2 
.func irexp(v) {(vc0+vc1*v**vc2)*(1.0+tc1*(temp-25)*exp(tc2*(temp-25)))+(vc3*exp(vc4*v))*(1.0+tc3*(temp-25)*exp(tc4*(temp-25)))}
d1 1 C zener
g1 C 1 value = {irexp(v(C,1))}
d2 2 C zener
g2 C 2 value = {irexp(v(C,2))}
.model zener d
***** flag parameter *****
+level = 1                     
***** dc model parameter *****
+ is = 1e-15		   n = 1		  rs = 3.137e-1
+ibv = 1e-3		 nbv = 1e-2		  bv = 18.55
***** capacitance parameter *****
+cjo = 1.922e-11	   m = 3.555E-1		  vj = 5.34 
+ fc = 0.5
***** temperature coefficient *****
+tnom = 25		  eg = .75		 xti = 3
+trs1 = 1e-3		tbv1 = 5.267e-4
.ends PEC3815CS-AU
*$
